# packages/dotlrn-ecommerce/lib/categorized-products.tcl
#
# shows products listed under a category (ec_subcategories)
#
# @author Deds Castillo (deds@i-manila.com.ph)
# @creation-date 2005-07-12
# @arch-tag: 64c6a9f0-60d8-4adf-a7d8-3cda53ed6b68
# @cvs-id $Id: categorized-products.tcl~,v 1.1 2005/07/16 12:51:06 hamiltonc Exp $

foreach required_param {category_id} {
    if {![info exists $required_param]} {
        return -code error "$required_param is a required parameter."
    }
}

foreach optional_param {user_id restrict_to_one_p participant_id} {
    if {![info exists $optional_param]} {
        set $optional_param {}
    }
}

if {[empty_string_p $user_id]} {
    set user_id [ad_conn user_id]
}

if {[empty_string_p $participant_id] || [string equal $participant_id 0]} {
    set participant_id $user_id
}

if {[empty_string_p $restrict_to_one_p]} {
    set restrict_to_one_p 0
}

template::list::create \
    -name products \
    -multirow products \
    -elements {
        product_name {
            label "Product name"
        } 
        one_line_description {
            label "Description"
        }
        price {
            label "Price"
        }
        actions {
            label ""
            display_template {
                <a href="@products.shopping_cart_add_url;noquote@" class="button">Add to cart</a>
            }
        }
    }


db_multirow -extend { shopping_cart_add_url } products products {
    select p.product_id,
           p.product_name,
           p.one_line_description,
           p.price
    from ec_products p,
         ec_category_product_map m
    where m.category_id = :category_id
          and m.product_id = p.product_id
} {
    set shopping_cart_add_url [export_vars -base shopping-cart-add { user_id participant_id product_id }]
}