Developer Support. The Developer Support package adds several goodies: debug information for every page; the ability to log comments to the page instead of the error log, and fast user switching so that you can test pages as anonymous and as dummy users without logging in and out.

PostgreSQL. You can work directly with the database to do debugging steps like looking directly at tables and testing stored procedures. Start emacs. Type M-x sql-postgres. Press enter for server name and use service0 for database name. You can use C-(up arrow) and C-(down arrow) for command history.

Hint: "Parse error near *" usually means that an xql file wasn't recognized, because the tcl file is choking on the *SQL* placeholder that it falls back on.

Watching the server log. 

To set up real-time monitoring of the AOLserver error log,

less /var/lib/aolserver/service0/log/error.log

Make a list of basic tests to make sure it works

Other things to test: try to delete someone else's note. Try to delete your own note. Edit your own note. Search for a note.

It seems to me that a lot of people have been asking for some guidelines on how to write automated tests. I've done several tests by now and have found the process to be extremely easy and useful. It's a joy to work with automated testing once you get the hang of it.

Create the directory that will contain the test script and edit the script file. The directory location and file name are standards which are recognized by the automated testing package:

[service0 www]$ mkdir /var/lib/aolserver/service0/packages/myfirstpackage/tcl/test
[service0 www]$ cd /var/lib/aolserver/service0/packages/myfirstpackage/tcl/test
[service0 test]$ emacs myfirstpackages-procs.tcl

Write the tests. This is obviously the big step :) The script should first call ad_library like any normal -procs.tcl file:

ad_library {
    ...
}

To create a test case you call aa_register_case test_case_name.. Once you've created the test case you start writing the needed logic. We'll use the tutorial package, "myfirstpackage," as an example. Let's say you just wrote an API for adding and deleting notes in the notes packages and wanted to test that. You'd probably want to write a test that first creates a note, then verifies that it was inserted, then perhaps deletes it again, and finally verifies that it is gone.

Naturally this means you'll be adding a lot of bogus data to the database, which you're not really interested in having there. To avoid this I usually do two things. I always put all my test code inside a call to aa_run_with_teardown which basically means that all the inserts, deletes, and updates will be rolled back once the test has been executed. A very useful feature. Instead of inserting bogus data like: set name "Simon", I tend to generate a random script in order avoid inserting a value that's already in the database:

set name [ad_generate_random_string]

aa_register_case mfp_basic_test {
    My test
} {
    aa_run_with_teardown \
       -rollback \
       -test_code  {

       }
}

Now let's look at the actual test code. That's the code that goes inside -test_code {}. We want to implement test case API-001, "Given an object id from API-001, invoke mfp::note::get. Proc should return the specific word in the title."

      set name [ad_generate_random_string]
      set new_id [mfp::note::add -title $name]
      aa_true "Note add succeeded" [exists_and_not_null new_id]

To test our simple case, we must load the test file into the system (just as with the /tcl file in the basic tutorial, since the file didn't exist when the system started, the system doesn't know about it.) To make this file take effect, go to the APM and choose "Reload changed" for "MyFirstPackage". Since we'll be changing it frequently, select "watch this file" on the next page. This will cause the system to check this file every time any page is requested, which is bad for production systems but convenient for developing.

Once the file is loaded, go to ACS Automated Testing and click on myfirstpackage. You should see your test case. Run it and examine the results.

Now we can add the rest of the API tests. The complete test looks like:

ad_library {
    Test cases for my first package.
}

aa_register_case mfp_basic_test {
    Test One
} {
   aa_run_with_teardown \
       -rollback \
       -test_code  {
           set name [ad_generate_random_string]
           set new_id [mfp::note::add -title $name]
           aa_true "Note add succeeded" [exists_and_not_null new_id]

           mfp::note::get -item_id $new_id -array note_array
           aa_true "Note contains correct title" [string equal $note_array(title) $name]

           mfp::note::delete -item_id $new_id

           set get_again [catch {mfp::note::get -item_id $new_id -array note_array}]
           aa_false "After deleting a note, retrieving it fails" [expr $get_again == 0]
       }
}

See also the section called “Automated Testing”.